SSAO 新進展

Yeah! 利用了法線緩衝所提供的資訊後， SSAO (屏幕空間環境光遮蔽) 的效果迫真了許多。
開始感受到電腦繪圖算法的迷人之處，可惜再沒有人和我分享這份喜悅。




讓我嘗試簡單地解釋它的原理吧。
螢幕中的每一像素都會和它周圍的 N 個像素作比較，比較時有兩個因數需要考慮

1. 兩像素於三圍空間中的位置；深度較淺的像素會遮蔽較深的像素，而遮蔽的程度就取決於距離。
   
   
2. 兩像素的法線內積 (Dot product)；面向面的像素會比面向同一方向的像素較接觸不到外來的光線。
   

至於怎樣對周圍的 N 個像素取樣，就是整個算法中最令人頭痛的問題。當然取樣越多效果越理想，但實際經驗告訴大家 N 只可以不大於 32 左右。隨著取樣的數量受限，而又希望有比較廣闊的取樣範圍 (位置較遙遠的像素都可互相影響)，可用一些隨機取樣模式；不過暫時我只用了一個十字形的取樣模式，只要取樣範圍不太大是可以接受的。

uniform sampler2DRect texColor; // Color texture
uniform sampler2DRect texDepth; // Depth texture
uniform sampler2DRect texNormal;// Normal texture
uniform vec2 camerarange = vec2(1.0, 500);

varying vec2 texCoord;
const float aoCap = 1.0;
float aoMultiplier = 1000.0;

float pw = 1.0;  // Use (1.0 / screensize.x) for GL_TEXTURE2D
float ph = 1.0;

float readDepth(in vec2 coord)
{
 float nearZ = camerarange.x;
 float farZ = camerarange.y;
 float posZ = texture2DRect(texDepth, coord).x;

 return (2.0 * nearZ) / (nearZ + farZ - posZ * (farZ - nearZ));
}

vec3 readNormal(in vec2 coord)
{
 return normalize(2 * (texture2DRect(texNormal, coord).xyz - 1));
}

float compareDepths(in float depth1, in float depth2)
{
 float depthDiff = depth1 - depth2;
 const float aorange = 10.0;  // Units in space the AO effect extends to (this gets divided by the camera far range)
 float diff = clamp(1.0 - depthDiff * (camerarange.y - camerarange.x) / aorange, 0.0, 1.0);
 return min(aoCap, max(0.0, depthDiff) * aoMultiplier) * diff;
}

float calAO(float depth, vec3 normal, float dw, float dh)
{
 vec2 coord = vec2(texCoord.x + dw, texCoord.y + dh);
 float angleFactor = 1 - dot(normal, readNormal(coord));

 if(length(normal) == 0)
 angleFactor = 0;

 return angleFactor * compareDepths(depth, readDepth(coord));
}

void main(void)
{
 float depth = readDepth(texCoord);
 float ao = 0.0;

 vec3 normal = readNormal(texCoord);

 for(int i=0; i<8; ++i) {
  ao += calAO(depth, normal, pw, ph);
  ao += calAO(depth, normal, pw, -ph);
  ao += calAO(depth, normal, -pw, ph);
  ao += calAO(depth, normal, -pw, -ph);

  pw *= 1.4;
  ph *= 1.4;
  aoMultiplier /= 1.5;
 }

 ao *= 2.0;

 gl_FragColor = vec4(1.0 - ao) * texture2DRect(texColor, texCoord);
}

---

相關文章

• 初嚐 Shader 編程
• Starcraft 2 - Effects & Techniques
• iñigo quilez
• Discussion on opengl.org
• Discussion on gamedev.net