Squirrel 單元測試框架

暫時還無法找到一個給予 Squirrel 使用的單元測試框架，唯有自己做吧。Lua 的 luaunit 是一個好的起點，不需一天的時間就把它移到 Squirrel，且給它命名為 squnit (下載 / Download)。以下是一些使用範例：

dofile("squnit.nut", true);

class TestToto
{
 a = null;
 s = null;

 function setUp()
 {
  // Set up tests
  a = 1;
  s = "hop";
 }

 function test1_withFailure()
 {
  print("some stuff test 1\n");
  assertEquals(a , 1);
  // Will fail
  assertEquals(a , 2);
  assertEquals(a , 2);
 }

 function test2_withFailure()
 {
  print("some stuff test 2\n");
  assertEquals(a , 1);
  assertEquals(s , "hop");
  // Will fail
  assertEquals(s , "bof");
  assertEquals(s , "bof");
 }

 function test3()
 {
  print("some stuff test 3\n");
  assertEquals(a , 1);
  assertEquals(s , "hop");
  assertEquals(typeof a, "integer");
  assertClose(0.01, -0.01, 0.02);
 }
} // TestToto

class TestTiti
{
 a = null;
 s = null;

 function setUp()
 {
  a = 1;
  s = "hop";
     print("TestTiti.setUp\n");
 }

 function tearDown()
 {
  // Some tearDown() code if necessary
  print("tearDown\n");
 }

 function test1_withFailure()
 {
  print("some stuff test 1\n");
  assertEquals(a , 1);
  // Will fail
  assertEquals(a , 2);
  assertEquals(a , 2);
 }

 function test2_withFailure()
 {
  print("some stuff test 2\n");
  assertEquals(a , 1);
  assertEquals(s , "hop");
  // Will fail
  assertEquals(s , "bof");
 }

 function test3()
 {
  print("some stuff test 3\n");
  assertEquals(a , 1);
  assertEquals(s , "hop");
 }
} // TestTiti

// Simple test functions that were written previously can be integrated in luaunit too
function test1_withFailure()
{
 assert(1 == 1);
 // Will fail
 assert(1 == 2);
}

function test2_withFailure()
{
 assert("a" == "a");
 // Will fail
 assert("a" == "b");
}

function test3()
{
 assert(1 == 1);
 assert("a" == "a");
}

TestFunctions <- wrapFunctions("test1_withFailure", "test2_withFailure", "test3");

// SqUnit().run("test2_withFailure"); // Run only one test function
// SqUnit().run("test1_withFailure");
// SqUnit().run("TestToto"); // Run only on test class
// SqUnit().run("TestTiti:test3"); // Run only one test method of a test class
SqUnit().run(); // Run all tests

還可以使用 squnit 本身來測試自己：

/* testSqunit.nut
 Description: Tests for the squnit testing framework
 Author: Ricky Lung (http://mtlung.blogspot.com/)
 Version: 1.0

 License: X11 License

 This set of files is published under the X11 License. You can do
 more or less anything you want to do with it.

 Permission is hereby granted, free of charge, to any person obtaining a copy
 of this software and associated documentation files (the "Software"), to deal
 in the Software without restriction, including without limitation the rights
 to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
 copies of the Software, and to permit persons to whom the Software is
 furnished to do so, subject to the following conditions:

 The above copyright notice and this permission notice shall be included in all
 copies or substantial portions of the Software.

 THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
 IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
 FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE X
 CONSORTIUM BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN
 ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION
 WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
*/

// This is a bit tricky since the test uses the features that it tests.

dofile("squnit.nut", true);

class TestSqUnit
{
 function mypcall(func, ...)
 {
  local args = array(0);
  for(local i=0; i<vargc; ++i)
   args.push(vargv[i]);

  try {
   func.pacall(args);
   return true;
  } catch(e) {
   return false;
  }
 }

 function testAssertError()
 {
  local has_error = !mypcall(error, null, "coucou");
  assert(has_error == true);
  assertError(error, null, "coucou");
  has_error = !mypcall(assertError, null, error, null, "coucou");
  assert(has_error == false);

  local f = function() {}
  has_error = !mypcall(f, null);
  assert(has_error == false);
  has_error = !mypcall(assertError, null, f, null);
  assert(has_error == true);

  // multiple arguments
  local multif = function(a, b, c) {
   if(a == b && b == c) return;
   error("three arguments not equal");
  }

  assertError(multif, null, 1, 1, 3);
  assertError(multif, null, 1, 3, 1);
  assertError(multif, null, 3, 1, 1);

  has_error = !mypcall(assertError, null, multif, null, 1, 1, 1);
  assert(has_error == true);
 }

 function testAssertEquals()
 {
  assertEquals(1, 1);
  local has_error = !mypcall(assertEquals, 1, 2);
  assert(has_error == true);
 }

 function testAssertClose()
 {
  assertClose(1, 1);
  assertClose(-1, -1);
  assertClose(0.1, -0.1, 0.2);
  local has_error = !mypcall(assertEquals, 0.1, -0.1, 0.19);
  assert(has_error == true);
 }

 function XtestXpcall()
 {
  local f = function() {
   error("[this is a normal error]");
  }
  local g = function(f) {
   f();
  }
  g(f);
 }
} // TestSqUnit

//SqUnit().run("TestSqUnit.testAssertEquals"); // Will execute only one test
//SqUnit().run("TestSqUnit"); // Will execute only one class of test
SqUnit().run(); // Will execute all tests